The Flash player has an issue where it will not load a crossdomain.xml file on a redirect. What this means is that setting the load policy has no effect, since it will only load the crossdomain.xml from the first domain, not the redirected one.

A consequence of this is when loading images from CDNs such as Edgecast, Akamai, etc., you will get Security Error #2122 when you attempt to get the width/height of the image. Luckily, there is a simple and straightforward solution (via @jesterxl).

All you do is reload the image using the redirected url, which is available in the LoaderInfo.url in the onComplete event listener of the first load. The benefit of doing this is that the second load comes from the cache, so it's basically instantaneous (or however long it takes to load the crossdomain.xml from the redirected url). Here's some sample code on how to pull this off.

import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;

function load(url:String):void
{
        var sprite:Sprite = new Sprite();
        var loader:Loader = new Loader();
        sprite.addChild(loader);
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
        var lc:LoaderContext = new LoaderContext(true);
        lc.checkPolicyFile = true;
        loader.load(new URLRequest(url), lc);
}
function onComplete(event:Event):void
{
        // the redirected url
        var path:String = LoaderInfo(event.target).url;
        var loader:Loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onReallyComplete);
        // swap out the old loader with the new one into the same container
        LoaderInfo(event.target).loader.parent.addChild(loader);
        LoaderInfo(event.target).loader.parent.removeChild(LoaderInfo(event.target).loader);
        var lc:LoaderContext = new LoaderContext(true);
        lc.checkPolicyFile = true;
        loader.load(new URLRequest(path), lc);
}
function onReallyComplete(event:Event):void
{
        var w:int = LoaderInfo(event.target).content.width;
        var h:int = LoaderInfo(event.target).content.height;
}